*save_checkpoint

*text_image chap_2.png center Chapter Two
*temp giantchat false
*temp hurtzagreus false
*temp charmolympusplan false
*temp tense false
*temp notryst false
*temp intimidatedaphrodite false


Elysium juts out of a rugged hill encrusted with gemstones. Mortals must take pick and hammer to the earth for such shiny treasures but here in the Underworld, they sprout out of rock like flowers.

The palace crowns the hill's peak, carved of onyx and adorned with mosaics of sapphire, ruby, and emerald. 

You stroll past the portico's ribbed columns, the great hall presided by your parents' matching thrones, the courtyard where a group of nymphs are weaving. 

Any other day, you might have joined them. Shared gossip over cups of nectar, watched souls form makeshift constellations above. 

Alas, you merely wave and hustle along.

*page_break Find Your Mother

You hear her before you reach the door to your chambers. Barking orders at the seamstress, demanding more @{(flower) crocus|daffodil|quince|nightshade} oil be added to your bath, scolding your brother for flirting with the servants.

"There you are!" she cries as soon as you walk in.

Persephone, Goddess of Spring and Queen of the Underworld, has the kind of presence that commands a room.

Her skin is the rich brown of a deer's coat, her eyes the dark green of a forest shedding winter from its roots. Her flowing auburn hair is crowned with flowers that never wilt, and even presiding over a selection of gowns strewn across a divan, she's a vision of beauty and dread.

No wonder mortals worship her so. 

"You're late," she declares.

@{(parentsrel) "I'm sorry, I didn't mean to delay so much. There was an empusa by the Dream Gate." Your words melt some of the coolness in her gaze.|"Tell that to the empusa I encountered by the Dream Gate," you snap, unfazed by her skewering glare.|You lift your hands, half to placate her, half to plead. "You can blame Aunt Hecate for that. One of her empusas was sniffing around the Dream Gate."}

*page_break

The queen looks to her youngest attendant, a slight, purple-haired nymph named Averna.

Relatively new to your mother's service—five decades, six at most—but already well acquainted with her favor.

"Averna, would you tell the King his cousin has let one of her beasts loose again? Thank you." 

The nymph nods, winking at you before disappearing into the shadows behind her. She's a lampad, borne of the Underworld's deepest, darkest depths, and thus able to move through them the same way you move through the Halfrealm: without restrictions.

Your mother turns back to you. "Well, what are you waiting for? Go make yourself presentable."

*fake_choice
    #I do as she asks without arguing.
        *set parents %+10
    #I roll my eyes but do as she asks.
        *set parents %+5
    #I take my time just to annoy her.
        *set parents %-10
        
At least that's the plan. Until your brother intervenes.

He waves you over to the fitting stand, where a seamstress is fussing over the hem of his peplos. They're usually worn by goddesses, but Zagreus doesn't concern himself with arbitrary gender conventions. What he cares about is looking good, and that he does, always. 

This morning, kohl lines his eyes and his dark hair has been pinned back with a silver circlet to match the glitter dusted across his cheeks.

"Thank the Fates you're back," Zagreus sighs. "I was beginning to worry you'd run off and I'd have to marry Ares in your stead."

What do you reply?

*fake_choice
    *if marriage < 3
        #"No need. Unlike [i]some[/i] Underworld deities, I take my duties seriously."
            *set dutiful %+10
            *set Zagreus %-10
            *set hurtzagreus true
            Zagreus rolls his eyes.
        
            "[i]Some[/i] Underworld deities can tend to their duties and have fun. The two are not mutually exclusive. You should try the latter sometime, sister. It seems you're in dire need of it."

            Your annoyance flares into anger.

            "Yes, I'm sure gallivanting around the woods by day and drinking the realms' brothels dry by night is taxing work indeed," you scoff.

            The words are sharp with judgment, but he pretends they don't cut.

            "Oh, I can assure you it is. At least, if you're doing it right." 
            
            He winks at the seamstress, who smiles at him eagerly.
    #"Ares should be so lucky. You would make a wonderful husband, brother."
        *set charm %+10 
        *set Zagreus %+10
        "Can you imagine? Me? With an Olympian?" He pauses to consider it, then adds, "Then again, they are a beautiful bunch, and you know I have a weakness for beauty."
        
        "A claim I'm sure the realms' finest brothels can corroborate."

        "And the not-so-fine ones." He winks at the seamstress, who grins up at him wickedly.
    #"How altruistic of you. Did you slip and hit your head at the brothel?"
        *set demure %-10
        *set Zagreus %+10
        Zagreus brings a hand to his chest in a show of feigned indignation. 

        "Hey! I do things for others all the time. Just ask the triton I spent the night with. I'm sure he'll agree I'm a [i]very[/i] generous god indeed."

        You turn to the seamstress. "How do you resist the urge to stab him with the pins?"
        
        A wicked smile curves her lips. "I don't."

        "She knows I don't mind a little pain," Zagreus teases.
 
        Fates, he's incorrigible. 
    #"Spare me the mockery, brother. I'm not in the mood for your whining."
        *set ruthless %+10
        *set Zagreus %-5
        *set hurtzagreus true
        "What? If you want to be coddled, go back to whichever brothel you spent the night in," you add, ignoring his hurt expression.

        "Believe me, I would love nothing more," he mutters. "Unfortunately, Mother threatened to send a Fury to fetch me if I dare."

        A smile cuts into your cheeks.

        "I would pay good coin to see that."

        The goddesses of vengeance and retribution are not to be messed with.

*page_break

"You two better not make me come over there," your mother threatens.

"You heard her," you warn Zagreus.

He pretends he isn't terrified of her and gestures at a game of petteia laid out on a side table.

"Do me a favor, will you? Move that piece a couple of squares forward for me, the one in the center. Averna agreed to teach me how to shadow-walk if I beat her."

He leans in to whisper in the seamstress's ear. You roll your eyes and examine the petteia board.

At first glance, it appears Zagreus and Averna are evenly matched, for they've captured the same number of pieces from the other. But, upon further inspection, you realize she has set a trap for him, and moving the piece he asked you to would likely result in his defeat.

*fake_choice
    *if hurtzagreus
        #I do it anyway; he doesn't deserve to win.
            *set ruthless %+10
            *set Zagreus %-5
            *set petteia 1
    #I do it anyway; he must learn to fight his own battles.
        *set leadership %+15
        *set petteia 2
    *if hurtzagreus = false
        #I move a different piece; I'll always protect my little brother.
            *set Zagreus %+15
            *set petteia 3
    #I move a different piece; I'll enjoy taunting him about it later.
        *set cunning %+15
        *set petteia 4
    #I move a different piece; I can't bear the thought of losing, not even by proxy.
        *set charm %-15
        *set competitive true
        *set petteia 5

Satisfied, you duck behind a divider carved with @{(epiali) snakes|bats|ravens|cats|spiders} and finally take a bath.

The warm, sweet-scented water's touch wraps around you, encouraging your mind to drift.

On the other side of the divider, you can hear Zagreus and the seamstress giggle. The Fates made him a god of hunting, a role he takes to heart. For him, everything is sport; anyone is prey.

It makes you wonder about your own lot.

*fake_choice
    #I love weaving nightmares and unleashing dread upon the mortal world.
        *set nightmares 1
        *set ruthless %+10
    #I love weaving nightmares and mediating between gods and mortals.
        *set nightmares 2
        *set diplomacy %+10
    #I would never question why the Fates gave me the ability to weave nightmares.
        *set nightmares 3
        *set dutiful %+10
    #I wish weaving nightmares didn't cause mortals so much suffering.
        *set nightmares 4
        *set ruthless %-10
    #I sometimes imagine what life would be like if I weren't a goddess at all.
        *set nightmares 5
        *set dutiful %-10

*if (nightmares = 1) or (nightmares = 2)
    You wouldn't change that even if the Fates themselves gave you the chance.

    Not because you trust their judgment above all things, but because you trust your own. This is your purpose by choice, as well as by design.
    *goto main02
*elseif nightmares = 3
    You simply weave them.

    Why do rivers always lead to the ocean? Why do saplings grow every time a wood nymph is born? Why must mortals die?
    
    Some things just are.
    *goto main02
*elseif nightmares > 3
    It's blasphemous to think so. Fear is the other side of hope. Without it, there is no balance.

    And yet, you often find yourself yearning for a different path.
    *goto main02
*else
    *goto main02

*label main02
*page_break

"Do you plan to stay in there all day?" your mother calls.

@{(parentsrel) "All done," you assure her|"Maybe," you taunt her|"Almost finished," you promise}.

You emerge from the tub, @{(flightstyle) shake your wings dry|pull in your shadows|slide your feet into your sandals} and slip into a robe.

A steaming glass of nectar awaits by your vanity. You take a seat and contemplate your appearance in the looking glass, running your fingers through your hair.

What color is it?

*fake_choice
    #A rich red, like my mother's.
        *set haircolor "red"
    #Inky black, like my father's.
        *set haircolor "black"
    #Buttery blonde, like my grandmother's.
        *set haircolor "blonde"
    #Deepest brown, like my aunt Hecate's.
        *set haircolor "brown"
    #A different shade, mine alone.
        *input_text haircolor

How do you style it?

*fake_choice
    #It cascades down my back, long and flowing.
        *set hair 1 
    #Into a crown of tight curls that frames my face.
        *set hair 2
    #Braided into lovely, intricate patterns.
        *set hair 3
    #Tied back with a beautiful headscarf.
        *set hair 4

It doesn't take much for it to look its best. 

Such is the might of divinity.

"Much better," your mother says.

You turn your attention to the selection of gowns on the divan.

Which one do you go for?

*fake_choice
    #The short, floaty chitoniskos favored by athletes.
        *set fitness %+10
        *set style 1
    #The drapey, low-cut chiton that hugs me in all the right places.
        *set demure %-10
        *set style 2
    #The dark and muted chiton, to match my father's.
        *set parents %+10
        *set stealth %+5
        *set style 2
    #The peplos embroidered with flowers, to match my mother's.
        *set parents %+10
        *set leadership %+5
        *set style 3
    #The modest peplos, with a matching himation to cover my shoulders.
        *set demure %+10
        *set style 3

You slide it on and let your mother usher you to the empty fitting stand while Zagreus studies the petteia board.

The seamstress tugs at your hem and tidies your neckline under your mother's close watch. 

It's unnecessary, all this fretting.

Grooming, sleeping, eating anything other than ambrosia or drinking anything other than nectar. They're little more than rituals. Things gods do for the pleasure and comfort they bring, rather than because they must.

"Stand next to your brother, let me take a good look at the pair of you."

You step off the stand and Zagreus shuffles closer.

*if hurtzagreus
    Now would be a good time to make amends.
    *choice
        #And I do. It's never too late to show grace.
            *set ruthless %-10
            *set Zagreus %+10
            "I didn't mean to be so short earlier. I'm sorry," you whisper.
            
            He bumps your shoulder with his.

            "I'm sorry too," he whispers back. "I know how much is expected of you today. I shouldn't have made light of that."
            *goto main03
        #And I do. It pays to keep him on my side.
            *set cunning %+10
            *set Zagreus %+5
            You summon a smile and bump his shoulder with yours.

            "Purple is definitely your color, brother. The Olympians won't be able to take their eyes off of you."

            He perks up, smoothing the folds of his peplos. "Why, thank you. You look dazzling yourself, sister."
            *goto main03
        #But I won't. I may have been unkind, but I wasn't dishonest.
            *set ruthless %+10
            *set Zagreus %-5
            "You look lovely, sister," Zagreus says. Graceful and charming, even if he keeps his distance.
            
            You merely grunt in return.
            *goto main03
*else
    *set Zagreus %+10
    "You clean up good, sister," he whispers, bumping your shoulder with his. "Though not as good as me, of course."

    "Of course."
    
    He yelps when you pinch his forearm. 
    *goto main03

*label main03
*page_break

Your mother gives you an appraising once-over. Before she can give her verdict, there's a knock on the door.

"Come in, dear," she says.

Something in the air shifts when the King of the Underworld enters the room.

The souls flitting around the balcony slow down. The seamstress retreats into a corner, head lowered. Even Zagreus's demeanor is different. Sharper, more sober.

Among mortals, the name Hades inspires a terror so primordial, they avoid uttering it. He's seldom depicted in their vases or their tapestries. Few statues are carved in his likeness, few temples erected in his honor.

Yet he is worshiped far and wide, at every funeral pyre and at every grave. Through secret rites and with sacrifices held above the earth so the blood flows down to the Underworld's gates. 

It shows.

He moves like a predator, careful and quiet. A dark and misty aura surrounds him, and raw power lurks beneath it. The god who earned the allegiance of Death himself.

The god whom the other gods fear.

*page_break Bow Before Him

@{(parentsrel) You curtsy eagerly|You give him a suggestion of a curtsy|You curtsy gracefully}. He marches up to your mother, unbothered by the effect he has on the room.

It's rare to see him away from his work—it's a relentless job, managing the dead—rarer still for him to leave his kingdom. The only thing he's more committed to than his work is his wife. He takes her hand in his and plants a kiss on her knuckles.

She brings her free hand to his pale face, her thumb lingering on the scar etched into his cheekbone. It reaches all the way up to his hairline, slicing through his right eye and rendering it a much lighter shade of gray than the left one.

A remnant of the Gigantomachy, the first war against the Giants. And a reminder that the Giants' weapons can do that which nothing else can; pierce—and brand—a god's ironclad skin. 

No matter how formidable said god may be.

*page_break

"Well, what do you think?" she asks, gesturing toward you and Zagreus.

He keeps his gaze on her. "Beautiful."

@{(background) How smooth of him|The god who broke your heart never once looked at you like that|You can't help but wonder if anyone will ever look at you like that|You feel a pang of sorrow for the mortal you once loved}.

"Get a chamber," Zagreus groans.

A smile tugs at your father's lips as he studies you both.

"What magnificent envoys my children make." He beams.

*if (marriage = 3) or (marriage = 4)
    *set demure %-15
    *set parents %-10
    "Envoys? That's one way to put it. Perhaps chattel would be more fitting," you @{(parentsrel) half-joke, half-reproach|lament|half-joke, half-reproach}.

    Your mother clicks her tongue. "Don't be so dramatic, it's merely dinner."
    
    "If there is to be anything beyond that, it will be because you agreed to it," your father reassures you, not for the first time. 
    
    You give him a @{(parentsrel) grateful smile|skeptical glare all the same|resigned nod}.
    *goto main04
*else
    @{(parentsrel) You perk up at the compliment and feel Zagreus do the same|Zagreus perks up at the compliment, but you refuse to give him the satisfaction|You perk up at the compliment and feel Zagreus do the same}.
    *goto main04

*label main04

Whatever this day holds…

*fake_choice
    *if (((parentsrel = 1) or (parentsrel = 3)) and (hurtzagreus = false))
        #I'm glad I have my family by my side to face it.
            *set parents %+15
            *set Zagreus %+10
    #I'll navigate it with poise and grace befitting a queen.
        *set leadership %+15
    #Olympus will be eating out of my hand by the end of it.
        *set charm %+15
        *set charmolympusplan true
    #I'll do right by @{(parentsrel) my parents and my realm|my realm, if not my parents|my realm, if not my parents}.
        *set dutiful %+15
        *set parents %+10
    #I'll face it with the unflinching resolve of a warrior.
        *set ruthless %+15

Out in the courtyard, you pile into your father's chariot. He pats the gleaming coats of the four huge horses that pull it before joining you. A wave of his hand is all they require to kick the ground and lift the chariot into the sky.

It's an unsettling feeling, @{(flightstyle) to fly without your wings|to be carried by something other than your shadows|to feel the solid ground under your feet while you're in the air}, but you do your best to ease into it and enjoy the view.

The Lethe is far behind you, but its sibling rivers coil around the realm like snakes. The blazing Phlegethon, the wailing Kokytos, the solemn Styx and the foreboding Acheron. 

You glide past the latter, maneuvering around a flock of white doves carrying bundles of ambrosia from Olympus, and halt before the Underworld's main gates.  

Their fearsome sentinel, the three-headed hound Cerberus, bows his heads. 

But he doesn't move out of the way.

*page_break

The Dream Gate is tucked away in the woods, too small for anything bigger than an empusa to try its luck slipping through it, and too close to the Lethe for the freshly dead to go near it.

But here is where Hermes and Iris bring them after their bodies are burned or buried. When their lips still remember the taste of food, their skin the touch of their loved ones. When they must be kept from the living, lest they become something far worse—and more dangerous—than dead.

There's a big difference between a friendly ghost and a hungry one.

It's why Cerberus takes his guarding duties so seriously. Your father summons his bident and slams the end against the chariot's floor. The sound reverberates around you, warning all those who might chance an escape that the King of the Underworld is passing through. 

And he doesn't show mercy to those who break his rules.

Only then does the loyal hound grant you passage. The huge gates screech open and the horses press on. 

As the chariot floats by, you spot the slight twitch of Cerberus's tail.

*fake_choice
    #I pet him; he's too adorable not to.
        *set daemonhandling %+20
        *set cerberusfriendly true
        "Who's a good boy?" you pout, rubbing behind each set of ears and scratching every one of his chins.

        His sighs happily, tail launching into a full wag.

        "You shouldn't indulge him," your mother chastises. "The dead and the damned will be less afraid of him if they catch him slobbering and whimpering so."

        You allow yourself a last rub before settling back into the chariot. The gates close behind you and Cerberus resumes his post.
    #I pet him; if only to keep him sweet.
        *set cunning %+20
        *set cerberusfriendly true
        Who wouldn't want a massive three-headed dog as an ally? Besides, you never know when you might need to make a quick escape yourself.

        You rub behind each set of his ears, scratch every one of his chins.

        "You remember your old friend ${name}, don't you? Yes, you do."

        He sighs happily, wagging his tail softly. Satisfied, you settle back into the chariot, ignoring Zagreus's smirk and your mother's disapproving glare. The gates close behind you and Cerberus resumes his post.
    #I keep my hands to myself; he's a sentinel, not a pet.
        *set ruthless %+20
        To treat him as such would undermine both his authority and your own, not to mention put mortals' safety at risk. 

        The dead and the damned expect a beastly daemon whose claws and fangs can make them remember physical pain, not a whimpering, tail-wagging pup.

        His heads remain bowed until the gates close behind the chariot, and he resumes his post.
    #A pet might undermine his authority; I smile cordially at him instead.
        *set diplomacy %+20
        Should the dead and the damned view him as weak, they might be more inclined to attempt an escape. You refuse to take that risk. 

        But you don't have to be rude about it.
        
        "Thank you," you whisper.

        His bow deepens. Once you're through and the gates close behind you, he resumes his post.
        
*page_break 

The horses traverse the thick darkness on the other side in a blink. But they don't slow down after surfacing in Hellas.

No, they pick up the pace, flying up, up, up. Beyond the mortal realm's highest peaks, and over the threshold between the earth and the heavens.

Here, the sky is a blue so pure it makes you squint, the clouds thick and fluffy as whipped cream. The air should be cold and spread thin, but it kisses your cheeks with the mildness of a coastal breeze.

Olympus is carved into the clouds themselves. A city so polished, so gleaming, it almost stings to behold directly. But you do, marvelling at the domed ceilings, the wispy waterfalls, the lush greenery sprinkled with golden ambrosia.

The sacred plant can be found only on Olympus's slopes, for there is where the Primordials—the oldest and most powerful deities in the pantheon—fought an ancient war, and bled.

You can hear the buzz of bees in the distance, echoing like the cries of the damned in the Underworld. They'll be hard at work collecting pollen from the ambrosia and turning it into the honey-like liquid that coats your food and sweetens your wine. 

The honey-like liquid which grants you immortality.

*page_break

As the chariot nears Zeus's sprawling palace, you make out three figures waiting on the great portico's steps.

King Zeus, dark-haired and glowing bright as the lightning bolts he can summon at will. His wife Hera, decked in golden finery to match her golden complexion. And Prince Ares, the god who @{(marriage) might become your husband|might become your husband|they would have you marry|will never be your husband}.

The horses land, graceful as birds, and your father leads the charge, stepping off the chariot.

"Welcome back, my friend." Zeus's smile is as wide as his arms. "It has been far too long."

Your father tilts his chin down. A show of respect instead of deference. 

"Indeed."

You take the opportunity to size up Ares while they exchange pleasantries.

*page_break He Has Certainly Grown

He towers over his parents, a vision of strength in a leather cuirass over a short, blood-red tunic. Clean but simple garb, nothing like the ornate armor mortals like to depict him in. You can't help but notice the way it clings to his wide shoulders, the muscles rising and falling beneath his olive skin.

As for his face, it's both familiar and strange. The firm, angular shape of it is new, but the way his bronze hair frames it and the warmth of his hazel eyes match your memories.

When they find yours, his lips shoot up, coaxing the dimples out of his cheeks. Giving you a glimpse of the tender-featured boy he used to be instead of the hardened warrior he has become.

What do you do?

*choice
    #Greet him first; marriage or no, he looks sweet as ambrosia cake and I wouldn't mind a bite.
        *set fancyares true
        You stroll toward him, hips swaying, keeping your gaze on his even as you curtsy.

        "Ares," you say, making his name sound like an invitation.
        *if demure < 40
            *set Ares %+15
            *set maverickgoddess %+10
            @{(background) It's easy—you've played this game a thousand times|You've been out of the game for a little while, but that doesn't mean you don't know how to play it|Just because you're inexperienced in this game doesn't mean you don't know how to play it|You've been out of the game for a little while, but that doesn't mean you don't know how to play it}.

            "$!{name}. Pleasure to see you again."

            He sounds flustered already. Good—this should be a fun game indeed.
            
            "Pleasure is all mine," you tease.
    
            There's something so wickedly delightful about making a big, strong god blush. You turn your attention to his parents, but your mind is hard at work on how to make it happen again.
            *goto main05
        *else
            *set maverickgoddess %-10
            "Pleasure to see you again."

            But Zeus lets out a thunderous laugh as you utter the sentence, drowning it out. Whatever Zagreus told him must've been hilarious indeed, because he slaps your brother's shoulder and grins widely.

            "Well, you are welcome to our grounds any time, my boy," he says.

            Ares leans forward, frowning. "My apologies, I didn't quite get that."

            The words draw everyone's eyes and you suddenly feel mortified. Flirting in front of one's parents doesn't come naturally to anyone, @{(background) including seasoned seductresses such as yourself|let alone to those who haven't seduced anyone in a while|but especially to those who've never seduced anyone|let alone to those who haven't seduced anyone in a while}.

            "Uh…I…Hi," you mumble awkwardly.

            His eyebrows rise, but his smile stays firmly in place. "Hi."
            *goto main05
    #Follow the proper etiquette; I curtsy before his parents first, then him.
        *if dutiful > 40
            *set Ares %+10
            *set olympusinfluence %+10
            Queen Hera and King Zeus give you an approving look. 

            "$!{name}, how you've grown," Zeus croons. "As beautiful as your mother."

            "Indeed," Hera agrees. "I trust you remember my son? You two used to be quite the troublesome duo when you were godlings."
            
            You nod at her before smiling at Ares.

            "Of course. Pleasure to see you again."

            "The pleasure is all mine." 
            *goto main05
        *else
            *set olympusinfluence %-10
            *set Ares %+5
            It must be a very inadequate curtsy, however, for Queen Hera and King Zeus clearly aren't impressed by it when you meet their eyes anew.

            "That will suffice, I suppose," Zeus mumbles.

            You lift your chin. Did he expect you to scrape your knees on the hard marble floor? Kiss his feet, perhaps?

            Hera gestures toward Ares, and though there's no malice in her voice when she speaks, it definitely isn't warm.

            "I trust you remember my son? You two used to be quite the troublesome duo back when you were godlings."

            You brave a glance at him. At least [i]he's[/i] still smiling at you.

            "Of course."

            "Pleasure to see you again." He beams.
            *goto main05
    #Play it cool; return his smile but ingratiate myself with his parents
        "King Zeus. Queen Hera. Pleasure to see you again."

        *if charm > 40      
            *set Ares %+10
            *set pantheonplayer %+10
            "The pleasure is all ours," King Zeus croons. "It was high time for a reunion."

            "I couldn't agree more." You nod. "I've missed Maia's cooking."

            His laugh makes the air around you crackle.
            
            "Her talent in the kitchen is remarkable indeed," Hera adds before gesturing toward Ares. "I trust you remember my son? You two used to be quite the troublesome duo back when you were godlings."

            "Of course." You face Ares, let your grin take over your face. "I could never forget the god who taught me how to play knucklebones."

            A blush creeps into his cheeks. 
            
            "Big mistake, as I recall it. I never won a game after that."
            *goto main05
        *else
            *set pantheonplayer %-10
            It comes out a lot more forceful than you'd intended.

            Zeus frowns and Hera blinks.

            "$!{name} is so excited to be here." Your mother @{(parentsrel) comes to your rescue|cuts in, making you bristle even further|comes to your rescue}. "And who wouldn't be eager to catch up with such an esteemed old friend?"

            A blush creeps into Ares's cheeks. He opens his mouth, but Zeus speaks before he has the chance.

            "I am certain the feeling is mutual," the god croons. "These two used to be quite the troublesome duo back when they were godlings."
            *goto main05
    *if (marriage > 2) and (charmolympusplan = false)
        #Ignore him; I follow my father's lead, nodding at Zeus politely.
            *if ruthless > 40       
                *set Ares %-5
                *set underworldinfluence %+10
                You stare straight past Ares, keeping your chin up as you face the King. 

                Zeus regards you with a mixture of curiosity and wariness. Good. He should know to tread lightly around you.

                "$!{name}, how you've grown," Hera greets you. "You remember my son Ares? You two used to be quite the troublesome duo back when you were godlings."

                You hold the God of War's gaze just long enough to acknowledge his existence. "Sure."
            
                His smile falters, but he doesn't fully retract it. "I suppose I've changed quite a bit since, though I never did sprout those wings I was so eager for back then. Either way, it's a pleasure to see you again."
                *goto main05
            *else
                *set underworldinfluence %-10
                *set Ares %-10
                "$!{name} is delighted to be here," your mother intervenes. "Aren't you, daughter?"

                Fury rises within you, but you force yourself to swallow it down. "Indeed."

                You have no choice but to agree with her. The only thing that would make you look weaker than your mother speaking for you is squabbling with her publicly because of it.

                Zeus watches you closely. Beside him, Hera gestures toward Ares. "You remember my son? You two used to be quite the troublesome duo back when you were godlings."

                You give him a half-hearted bow. "Sure."

                His brow furrows and the smile vanishes from his face. 
                
                "Pleasure to see you again," he mumbles.
                *goto main05

*label main05
*page_break

Zeus wraps a brawny arm around your father's shoulder, leading him up the stairs and into the glittering palace.

"Zagreus, dear," your mother calls. "You must tell Hera about the phoenix you spotted in the woods the other day."

A blatant attempt at forcing you to walk alongside Ares, of course. One Hera goes along with.

"A phoenix in the Underworld?" She sounds a little too interested, her eyes a little too keen. You can see why the poets rave about them—a lovely amber shade, soft and round, and framed by long, thick lashes. "Tell me everything."

Zagreus @{(hurtzagreus) obliges|raises an eyebrow at you. Only when you nod does he oblige}, leaving Ares no choice but to fall into step beside you. 

"Subtle as a blade to the gut, those two," he says sheepishly.

Then he pulls something out of his pocket. It's the size of his palm, and neatly wrapped in cloth. "I brought you something, by the way."

*page_break Open Ares's Gift

You gingerly unravel the cloth to reveal an amber dome glistening with syrup. Ambrosia cake, still warm against your fingers.

"I made a fresh batch this morning. Thought you might fancy a pick-me-up after the journey. I remember how much you used to like them. That might've changed, mind you. You don't have to eat it, of course." The words stumble from his lips. He winces, as though regretting them, and eyes you nervously. "Fates, I'm rambling. Sorry."

What do you do?

*fake_choice
    #Take a bite; and toy with him a little while I'm at it.
        *set Ares %+10
        *set demure %-10
        *set acceptedcake true
        You hold his gaze as you dip your tongue in the syrup pooling at the top of the cake. His dimpled cheeks turn redder than his tunic, but he can't seem to tear his eyes away.
        
        The cake melts in your mouth. It's as delicious as it looks, and you can scarcely believe he's made it himself.  

        "You're quite the baker. I wonder what other talents those big, strong hands of yours possess," you taunt before strolling ahead.

        "I…well…" he stutters, so stunned it takes him a moment to catch up.
    #Put him at ease; smile reassuringly before taking a bite.
        *set Ares %+10
        *set charm %+10
        *set acceptedcake true
        It's even more delicious than it looks.

        "That is, hands down, the best ambrosia cake I've ever had."

        His cheeks turn redder than his tunic, but his smile deepens.
        
        "All credit goes to Maia," he says, and you can tell he means it. "It's her recipe."

        "How is the lovely nymph doing?" you ask. "Last time I saw her, she was chasing you out of the kitchens with a broom."

        "Hasn't changed one bit. In fact, she chased me out of the kitchens with a broom earlier today."

        "I'm sure you deserved it."
    #Accept the gift, it would be rude not to, and I don't wish to be rude.
        *set dutiful %+20
        *set Ares %-5 
        *set distantares true
        *set acceptedcake true
        "That is very thoughtful of you. Thank you."
        
        "You really don't have to eat it," he reassures you.

        But you wave him off and take a small bite. It's so delicious, you almost lose your composure. You manage to tilt your chin down and get a grip of yourself.
        
        "A fine gift indeed."

        That pleases him, but there's an awkwardness to his words. "You're most welcome."

        You resume your journey in stilted silence.
    #Refuse the cake; I don't fancy it right now.
        *set Ares %-10
        *set ruthless %+10
        *set distantares true
        As delicious as it looks, and as good as it smells, you're not really in the mood for something @{(fancyares) sweet. Other than him, of course|sweet}.

        "I'm afraid I'll have to decline," you say, handing the cake back to him.

        Disappointment clouds his face. 

        "Of course."

        "Are you upset?" you ask, @{(fancyares) feeling guilty|frowning}.

        "What? No, I…sorry."

        You resume your journey in awkward silence.
*page_break

@{(distantares) It must be a rather loud silence, however, for Hera notices it and tosses her son an over-the-shoulder glare|Your exchange bought you some privacy, for the others are almost at the great hall's entrance}.

"Are you still as fond of @{(hobby) weaving?|sports?|music?|games?}" he ventures, @{(distantares) no doubt to appease her|resuming the journey but at a leisurely pace. As though he isn't too keen to join them}.

"Indeed. What about you?"

@{(hobby) "I'm hopeless. The loom would weep if it saw me coming."|"Well, I used to love wrestling." He hesitates. "But after taking on my duties, it sort of lost its fun."|"I'm afraid my musical talent is still non-existent."|"I'm hopeless at strategy. That's my sister Athena's forte."}

"I meant, what hobbies do [i]you[/i] have, not whether you enjoy mine," you clarify.
*if distantares
    Was it not obvious?

    He blinks. "Oh. That makes more sense."

    Fates, this is going terribly.
    *goto pregreathall
*else
    @{(hobby) "Though now I'm curious. What did you do to that poor loom?"|"Though I'm sorry to hear that. I can see how it might happen. I struggle to find joy in weaving, now that I must do it every night."|"Though I refuse to believe it. Have you tried percussion? You've certainly got the arms for it."|"Though now I know you're an easy mark, I may have to challenge you to a game of petteia later."}

    @{(hobby) That makes him chuckle|He nods|He blushes anew. At this point, his cheeks are more pink|That draws a chuckle from his lips}.
    *goto pregreathall

*label pregreathall

"To answer your question," he offers, "baking. That's what I love doing. That's all I would do if…if things were different."

*page_break

Before you can inquire further, you reach Olympus's great hall. 

Though you suppose it's less a hall and more a garden.

Green loan bleeds into polished marble floors, vines twist around gold-trimmed columns, water cascades from a nest of clouds into a crystalline pond dotted with lotus flowers. Beyond it, an apple orchard perfumes the air. Around it, loaded berry bushes draw bees and peacocks. The birds' gold and blue trains mimic the pattern on Queen Hera's dress, and they wear it almost as gracefully.

On the great table in the center of the room, golden platters piled high with meat, cheeses, and grapes drizzled with ambrosia have been laid out, and silver pitchers of nectar scattered between them. 

If you could feel hunger the way mortals do, you're certain your stomach would grumble at the sight of it.

"Esteemed guests," Zeus booms, taking his place at the head. "Let us eat, drink, and be merry."

*page_break Feast Away

Predictably, you're sat next to Ares. He passes you every platter before he serves himself, thanks every cupbearer who fills up his glass. @{(distantares) With you, he's nothing but polite. But he does keep his distance, cautious not to accidentally brush his fingers against yours or lean in too close|His excitement about each dish is almost contagious, and being in his presence reminds you of how easy it feels to talk to him}.

"[i]What[/i] is in this?" Zagreus asks. His mouth is full and, for a moment, you fear your mother might actually strangle him.

"Pinch of salt in the ambrosia. Oh, and rosemary shoot skewers to roast the lamb," Ares answers.

Zeus's lips press together beneath his thick, well-groomed beard.

"My son thinks himself God of the Hearth," the King says. "Alas, it is battle he rules over, and battle he must make. Fates guide him should the Giants move against us."

Ares shifts uncomfortably in his seat.

"Zeus," Hera warns. 

But the thunder god ignores her. Instead, he flicks you and Zagreus a conspiratorial grin, as though he's joking and you're in on it.

"Forgive my wife. She has a soft spot for their kind on account of her old friend. I'm sure you've heard of him. In fact, he's currently rotting in your very realm's darkest pit."

*page_break Argus Panoptes

Of course you've heard of Argus Panoptes. The hundred-eyed Giant who faithfully served Hera after the war. Too faithfully, according to the gossip.

His very spear is kept in your father's armory, under lock and key, as is every weapon belonging to Tartarus's prisoners.

"She even adorned the tails of her favored bird with his eyes, after he lost them," Zeus adds, waving his fork at the grazing peacocks. Hera's knuckles are white from gripping hers. If it wasn't forged of adamant, you're certain it would snap.

"I did. He saw the world so differently. He might've been a fierce warrior but, beneath all the brawn, there was a soft heart," she sighs. "Or so I thought."

"Then he brutally attacked one of your priestesses. That wasn't very soft-hearted of him, was it? Thank the Fates Hermes was there to stop him." Zeus shakes his head, then returns his attention to Ares. "Now there's a god who understands what we're up against. It's why he's doing everything he can to prevent it."

It's as much praise for Hermes as it's insult to Ares. It's also disrespectful to Hera. Hermes is Zeus's illegitimate son, after all.

The thunder god doesn't seem too worried, however. No, he glares openly at his son and continues, "Mortal warfare is child's play, compared to facing a warrior forged of stone."

*choice
    #I stick up for Ares; he doesn't deserve to be ridiculed so.
        @{(distantares) Clumsy attempts at conversation aside, you can't help but|You} feel for him, wilting in his chair like some trampled flower.

        "I have no doubt Ares would rise to the occasion," I say firmly.

        *if ruthless < 40
            *set Ares %+10
            *set olympusinfluence %+10
            *set outcome "defendedares"
            Ares shoots you a @{(distantares) surprised|grateful} glance. 
            
            "I'll certainly try." He sounds confident, looks it too, as if emboldened by your support.

            Hera gives you an appreciative nod.
            *goto postdinnerhappy
        *else
            *set tense true
            *set olympusinfluence %-10
            *set outcome "madolympians"
            Ares stiffens.

            "Standing up for your old friend. How very noble of you." Zeus smirks. "But it's not decency that will beat the Giants. It's might."
            *goto postdinnertense
    #I stick up for mortals; their suffering shouldn't be belittled so.
        *if dutiful < 50      
            *set peoplepleaser %+20
            *set outcome "defendedmortals"
            *set tense true
            "Mere skirmishes? You wouldn't dare call them that, if you saw the state of the dead who meet their end on the battlefield."

            "$!{name}," your mother warns. 

            Zeus waves her off and fixes his steely gaze on you.
            
            "How decent of you," he snarls. "But it's not decency that will beat the Giants. It's might."
            *goto postdinnertense
        *else
            *set peoplepleaser %-10
            *set outcome "diffusedolympians"
            You're about to speak up, but Ares beats you to it.

            "I will fight to the best of my abilities to keep the realms safe," he says. Gently, as though unbothered by his father's obvious insult. 
            
            Worse, as though he's used to hearing it.
            *goto postdinnerhappy
    #I say nothing; there is more to learn—and gain—from watching and listening.
        *if cunning > 40
            *set maverickgoddess %+20
            *set outcome "madolympians"
            *set tense true
            "Zeus," Hera hisses this time.

            Zeus's face hardens.
            
            "The boy is prattling on about seasoning, for Fates' sake."

            You note Ares's resigned sigh, how Hera folds into herself, a peacock drawing in its tail. This is a well-worn argument, re-hashed many times over.

            "I fail to see how that prevents me from fulfilling my divine duties," Ares says gently.

            Zeus's lips twist upward, but there's nothing humorous about his expression—nor his next words.

            "And I fail to see how it doesn't embarrass you."

            Ares shrugs. Interesting that a god known for his brutality in battle would behave so nonchalantly in the face of such a blatant insult.
            *goto postdinnertense
        *else
            *set maverickgoddess %-10
            *set outcome "diffusedolympians"
            You sense a well-worn argument teetering at the tips of their tongues.
            
            You wait for it to be unleashed upon the table, wondering what it might reveal about Olympus's inner workings.
            
            But Hades clears his throat, using that solemn demeanor of his to command everyone's attention.
            *goto postdinnerhappy
    #I lighten the mood; my signature charm is just the tonic for this tension.
        "I've heard the stories of your might in battle. How you fought alongside my father to defeat the Titans and keep mortals safe. Tell me, how true are the poets' ballads?"

        *if charm > 40
            *set pantheonplayer %+20
            *set outcome "diffuseddolympians"
            Your compliment makes Zeus puff up his chest. He turns his focus away from Ares. You feel the God of War instantly relax, as though grateful for the respite.
            
            "Well, they have certainly embellished some elements," Zeus concedes, scratching his beard. "But the glory they shower upon us was earned. Giants make the fiercest of adversaries, after all. I'd wager we could still make them cower in their sandals. Wouldn't you agree, old friend?"
            *goto postdinnerhappy
        *else
            *set pantheonplayer %-10
            *set outcome "madolympians"
            *set tense true
            The compliment backfires, emboldening Zeus instead of appeasing him.

            "True enough for my son to know he should do better," Zeus snarls. "The bloodbath wreaked by the Giants will be like nothing he's ever witnessed before."

            Ares stiffens. 
            *goto postdinnertense

*label postdinnerhappy
*page_break

"Let us hope it doesn't come to that," your father states, raising his cup and taking a sip.

His words chase away the storm brewing in Zeus's eyes.
            
"How right you are," the King agrees, settling back into good-natured cheer. "Now, let us turn our attention to sweeter matters. Who's ready for dessert?"

The air around the table lightens as the feasting continues, aided by pleasant chatter and plenty of nectar.
*goto aresquestion

*label postdinnertense
*page_break

"Let us hope it doesn't come to that," your father offers.

Zeus nods, but a storm rages behind his eyes.

"I suppose you're right, old friend," he concedes, resuming his meal.

You drag chunks of lamb around your plate with your fork, and everyone works hard to pretend the mood around the table hasn't spoiled. Still, the conversation is slow, Zagreus's jokes don't quite land, and Hera's questions about Elysium's fauna feel forced.

*label aresquestion
*page_break

"Shall we retire to the gardens?" Hera suggests after the last of the platters have been cleared.

"Excellent idea," your mother agrees, far too quickly and eagerly for it not to be some sort of ploy. 

Your suspicions are confirmed when she shoots you a pointed look. The same pointed look you spy Hera giving Ares. 

So that's where they'll address it, then. Your union.

Ares was right. Subtlety is far from their strong suit.

*page_break

Everyone rises and begins making their way to the fluffed-up divans scattered by the pond. 

Everyone but Ares, who hangs back and gestures for you to do the same.

"I believe this is the part where they engage in thinly veiled marriage negotiations involving copious amounts of guilt-tripping," Ares whispers, glancing at your families. "How would you like to skip all that and go on an adventure instead?"

How rebellious of him. 

"You don't wish to be married?" you ask with a frown.

"I don't wish to be ambushed. Besides, there's something in the oak grove I think you might like."

What do you do?

*choice
    *if distantares = false
        #I agree. I would love to sneak away with him.
            *set Ares %+15
            *set demure %-5
            *set wentwithares true
            *set fancyares true
            *goto sneakaway
    #I agree. I would love to get reacquainted in private.
        *set charm %+5
        *set Ares %+5
        *set wentwithares true
        *goto sneakaway
    *if parentsrel = 2
        #I agree. I would love to make my parents mad.
            *set dutiful %-10
            *set parents %-5
            *set wentwithares true
            *goto sneakaway
    #I agree. I would love to go on an adventure.
        *set Ares %+5
        *set fitness %+10
        *set wentwithares true
        *goto sneakaway
    *if marriage < 3
        #I agree. I would rather negotiate with him directly.
            *set leadership %+10
            *set Ares %+5
            *set wentwithares true
            *set aresmarriagetalk true
            *goto sneakaway
    #I agree. I would also rather not be ambushed.
        *set dutiful %-10
        *set Ares %+5
        *set wentwithares true
        *goto sneakaway
    *if fancyares = false
        #I refuse. I would rather we get reacquainted first.
            *set Ares %-10
            *set demure %+5
            @{(background) You're not against a frolic in the woods, under the right circumstances. These are not the right circumstances|It's been a while since you've frolicked in the woods. Not that it's what he's suggesting, but just in case|It's too soon for a frolic in the woods. Not that he's suggesting that kind of frolic. Or perhaps he is. You can't be sure, since you've never indulged in one. You also don't really know him. Not anymore|You're not against a frolic in the woods, under the right circumstances. These are not the right circumstances}.

            Better to take things slow.
            *goto refuse
    *if (parentsrel = 1) or (parentsrel = 3)
        #I refuse. I would hate to disappoint my parents.
            *set Ares %-5
            *set dutiful %+5
            *set parents %+10
            You glance at them, doing their best to honor their hosts. You know how hard your mother must work to sand down her sharp edges, and how much your father would prefer to be back home, where his power is strongest—and where it can be put to good use.

            If you must endure an ambush to honor them, so be it.
            *goto refuse
    #I refuse. I would hate to bring shame to the Underworld.
        *set Ares %-5
        *set diplomacy %+10
        *set parents %+5
        Such reckless behavior might reflect poorly on your realm—you won't take that @{(fancyares) risk, no matter how tempting it may be|risk}.
        *goto refuse
    *if marriage < 3
        #I refuse. I would rather negotiate all together.
            *set Ares %-5
            *set diplomacy %+10
            Knowing where he stands is important, but knowing where Olympus stands is paramount.
            *goto refuse

*label sneakaway

@{(distantares) "Lead the way," you tell him. Yes, reconnecting has gotten off to an awkward start. But perhaps this will remind you why you two were such close friends, once|"Just like old times," you tell him}.

He grins and guides you to a servants' passage tucked behind the feasting table. 

You make a beeline for the palace's manicured grounds, leaving behind lofty galleries and statues so realistic, you suspect they might be petrifications.

The grove isn't far. Much like Ares himself, it's both familiar and strange. A congregation of tall, stately oaks forming an emerald canopy pierced by golden light. Here, it never fades, never melts into dusk. It dances on the surface of a noisy stream and gilds the winding path.

Ares's demeanor changes as you tread it. He has been nothing but pleasant, of course. All endearing charm and courteous smiles. But now, weaving through the trees by your side, he seems different. More at ease.

*if aresmarriagetalk
    *gosub_scene subroutines marriagetalk
    *goto marriagetalk1
*else
    What do you wish to talk about?

    *choice
        #Marriage; I'd like to know where he stands.
            *set leadership %+5
            *set aresmarriagetalk true
            *gosub_scene subroutines marriagetalk
            *goto marriagetalk1
        #The grove; what does he want to show me?
            *set demure %-5
            "Where are you taking me?"

            "It's a surprise."

            He flashes you a mischievous grin and picks up the pace, following the stream deeper into the grove. It truly is the perfect spot to hide from overbearing family. 
            
            Or indulge in a romantic tryst.

            You halt and study him closely. 

            If that's his idea of a surprise…

            *fake_choice
                #I'm more than up for it.
                    *set Ares %+10
                    *set demure %-10
                    You sidle up to him, stopping short of letting your arm brush against his.
                #I'm willing to consider it.
                    *set Ares %+5
                *if fancyares
                    #I'm not sure I'm up for it yet.                   
                        *set notryst true
                *if (background > 1) and (fancyares = false)
                    #I'll be so disappointed in him.
                        *set Ares %-5
                        *set notryst true
                        He doesn't seem like the type to entice unsuspecting goddesses to the woods before pouncing on them, but that doesn't mean he won't try it.
                *if fancyares = false
                    #I'm turning right back.
                        *set Ares %-15
                        *set notryst true
            
            "Did you lure me here for a romp in the woods?" you @{(notryst) accuse|tease}, @{(demure > 55) struggling—and failing—not to blush|pinning your gaze on his}.

            He almost trips over a rock.

            "What? Of course not!" he blurts out.
            
            His cheeks are turning @{(demure > 55) crimson too|a deep shade of crimson}, and he looks at you as though you might have suggested the pair of you dive into Tartarus. It
            *if notryst
                fills you with relief.

                @{(background) You're not against that sort of thing. Far from it. But|It's been a while since you engaged in such pleasures;|You've never engaged in such pleasures;|It's been a while since you engaged in such pleasures;} @{(fancyares) as tempting as enjoying his body might sound, you'd rather enjoy his company alone. For now, at least|with him, you're not certain you ever want to}.

                "Good."
                *goto drakonnest
            *else
                stings a little.
                
                "Oh."

                You don't mean to sound so disappointed. He blinks at you when he realizes.

                "I would never…I definitely wasn't luring. That's not why I brought you here," he stammers, growing more flustered with each word. "There was no luring involved, is what I'm trying to say. But if a [i]romp[/i] is something you want I, well, I…"

                He takes a deep breath before adding, "Fates, I'm rambling again."

                *choice
                    #He is and it's adorable.
                        *set Ares %+10
                        *goto aresextraflirt
                    #He is and it's hilarious.
                        *set Ares %+5
                        *goto aresextraflirt
                    #He is and it's exasperating.
                        *set Ares %-5
                        You narrow your eyes at him. "Point taken. Let's move along, shall we?"

                        You shove past him and stalk off.

                        "Wait," he calls out, blocking your path.
                        *goto drakonnest
        #The Giants; are they that much of a threat?
            *set diplomacy %+5
            *set giantchat true
            As the God of War, he must have some valuable insights. 

            "Is your father right? Is there truly another Gigantomachy on the horizon?"

            Some of the tension returns to his shoulders. He picks up a pebble and tosses it into the stream. It skitters across the surface, leaving a trail of ripples in its wake.

            "I don't know," he sighs. "Sometimes I feel like he wants there to be."

            "How so?"

            Ares shrugs, but the set of his jaw is hard, and his gaze serious. "To relive his youth, perhaps. Or to teach me a lesson. You heard him at the feasting table. I'm too soft."

            Zeus wouldn't go to war just to make a point, would he?

            "I don't believe the Giants' new queen is after a war, though," Ares adds. You can't tell if it's to put you at ease, or because he truly believes it.

            "Then why push into Hellas?" you venture.

            He stares at the glinting water.
            *goto talkofgiants2

*label marriagetalk1

So that's where he stands; he would marry you, in the name of peace.

"Still, I've witnessed how miserable and bitter unwanted unions can make those pushed into them," he adds, picking up a pebble and tossing it into the stream. It skitters across the surface, leaving a trail of ripples in its wake. "I'd rather avoid that. In fact, I have a proposal for you."

*page_break A What?

"Not that kind of proposal!" he blurts out, @{(wentwithares) almost tripping over a rock|stiffening}. "A suggestion, if you will."

A suggestion. Of course!

His skin is all flushed, and he has to clear his throat before he can squeeze his next words out.

"I suggest we have fun together. Take some time to get to know each other again. And whatever happens after that—[i]if[/i] anything happens after that—it does so because we agreed to it, on our terms. Not because our parents strong-armed us into it."

What do you think?

*fake_choice
    #Not only is it a perfectly reasonable suggestion, it also sounds fun.
        *set Ares %+10
        "I would love that," you grin. 
    #It's a perfectly reasonable suggestion and puts my future into my own hands.
        *set leadership %+5
        "Deal," you agree. 
    #It's a reasonable enough suggestion. No harm in giving it a go.
        *set diplomacy %+5
        "Sure," you shrug.    
    #It's a reasonable enough suggestion, but I'm not sure it's the right one.
        *set Ares %-10
        *set unsureaboutares true
        @{(marriage) You want what's best for the realms, but|You want to advance your position in the pantheon, but|You want to fall in love, so|You don't believe in marriage as an institution, so} you don't know how to feel about this. 

        About [i]him[/i].

@{(unsureaboutares) His face falls, as though he can sense it|"Good." He beams}.

@{(unsureaboutares) "Ares," you begin|"Good," you repeat}.
*goto drakonnest

*label aresextraflirt

"Don't worry, your virtue is safe with me," you @{(demure > 55) joke, surprised at your own audacity|joke}.

He goes a brighter shade of crimson, but a smile emerges beneath all the red.

"You mock me."

His arm brushes against yours.

"Perhaps a little," you breathe, suddenly aware of how close he is, and how good he smells. 

Sweet, like freshly harvested ambrosia.

*label drakonnest

@{(unsureaboutares) But|Then} he freezes, eyes darting toward the shadows between the trees before a shriek emerges from them.

*page_break

The sound jogs your memory. 

You cast an eye over the sparkling stream, the reeds flanking it, the oak branches brushing its rippling surface.

You've been here before.

This is the edge of drakon territory.

Drakon [i]nesting[/i] territory.

*page_break

You scan the shadows, half expecting to find a drakon's reptilian eyes staring back at you. To catch the flash of scales, hear the undergrowth crunch beneath the weight of approaching claws.

Another shriek echoes through the grove, much further this time.

"Wha—"

Ares brings a finger to his lips, cutting you off.

"Over there," he mouths, making for a gnarly oak with a hollow carved into the trunk.
*gosub_scene subroutines predrakon

*label drakoneggs1
*page_break

When he peers into the hollow anew, his face is all warmth and wonderment. 

"I've been looking after them since. It won't be long before they hatch, I don't think," Ares says, his voice low and soft.

One of the eggs proves his point by trembling.

"Perhaps you'd like to be here, when it happens?" he asks, gently stroking the egg's shell.

*fake_choice
    #Snuggling baby drakons? Sign me up!
        *set daemonhandling %+10
    #Studying baby drakons? Sign me up!
        *set daemonhandling %+5
        *set cunning %+5 
        You can be like one of those mortals who enjoy observing birds in their natural habitats. You've heard they decorate vases with their likeness, collect their fallen feathers and boast about rare sightings.

        The former two aren't so appealing, but the latter will certainly make a fun new way to tease Zagreus.      
    *if unsureaboutares = false
        #Sneaking away with him again? Sign me up!
            *set Ares %+10
            *set fancyares true
    #I'd rather not commit to anything.
        *set Ares %-10
        *set unsureaboutares true

@{(unsureaboutares) "Perhaps," you reply|"I would love that," you grin}.

@{(unsureaboutares) The ghost of a wrinkle furrows his brow|It pleases him to hear it}. 

Then he clears his throat and glances back in the palace's direction.

"I don't wish to return," Ares sighs, his voice still low enough for the stream's bubbling to muffle it, "but I fear we must. Testing my parents is one thing; openly defying them is quite another. I doubt they serve ambrosia cake in Tartarus."

"Nothing but endless suffering, I'm afraid."

*page_break Head Back

You take a different route this time, one that leads you through the apple orchard, and onto the gardens.

The scene that greets you is straight out of a vase. Zeus and Hera lounge on one lavishly cushioned divan, your parents on another. They're surrounded by grazing peacocks and jugs of nectar, and drenched in golden light.

But the vision of idyllic bliss is just that—a vision. 

For beneath it, the rulers face one another the way petteia players do—trying to guess at the other's strategy, while keeping their own hidden.

When you catch a glimpse of their conversation, you understand why.
*goto talkofgiants

*label refuse
*page_break

"We can't," you tell him @{(fancyares) softly|firmly}.

The ghost of a wrinkle furrows his brow, but he nods. "As you wish."

*page_break Join the Others

As soon as you do, more nectar is brought out and a scantily clad satyr sets up with a golden harp. Zagreus promptly claims a cushioned bench closest to him.

The lavish furnishings, the grazing peacocks, and the glinting water all conspire to create an idyllic scene, the kind mortals might paint on a vase. 

But it's an illusion. 

Your families sit on opposite divans, facing each other the way petteia players do—trying to guess at the other's strategy, while keeping their own hidden.

Hera is the one to make the first move.

"We are truly honored you were able to join us, Hades. Your commitment to giving mortals a chance at a peaceful afterlife is commendable. Pity it doesn't allow for much socializing."

Your father gives her a tight-lipped smile. "Pity indeed," he says, managing to sound convincing.

It doesn't suit him, all this bright, relentless light. Here in Olympus, it never fades, never melts into dusk. Though your father still looks formidable, he's as out of his element as a bat drawn from its cave before nightfall.

*label talkofgiants
*page_break

"I'm glad my message compelled you to take a break, old friend," Zeus @{(wentwithares) is saying|adds gravely}. "My concern that the Fates are testing us has only grown since. Your duty is to the dead, but mine is to the living. If the Giants are truly mobilizing, they're the ones who will suffer the most. Which, of course, would only increase the Underworld's workload."

He addresses your father, but it's your mother who answers.

"If war does break, we will be ready. To fight, and to handle the aftermath."

*if (wentwithares = true) and (giantchat = false)
    *goto talkofgiants1
*elseif wentwithares = false
    *goto talkofgiants1
*else
    Whatever might've followed is forgotten, however, when Hera spots you and Ares hovering by the pond.  
    *goto feastsetup

*label talkofgiants1

"What if Queen Periboia isn't after a war?" @{(wentwithares) Hera|Ares} proposes.

Silence.

@{(wentwithares) It doesn't deter her|You glance at him. Like you, he's sandwiched between his parents, hands clenched. But he doesn't shrink from the scrutiny he's earned himself}.

*label talkofgiants2

"Her kin have been imprisoned in Tartarus for, well, an eternity, her wife among them. I think she's angling for her release."

To agree to that would…

*fake_choice
    #Make us look weak.
        *set ruthless %+5
        *set giantresponse 1
        Not to mention give them an advantage.
    #Prevent bloodshed.
        *set giantresponse 2
        *set ruthless %-5
    #Allow us to negotiate.
        *set diplomacy %-5
        *set giantresponse 3
    *if criesofdead > 1
        #Be right and just.
            *set dutiful %-5
            *set giantresponse 4
 
@{(giantresponse) "You would have us strengthen their ranks?"|"If so, we should hear them out. For the sake of keeping the peace."|"It could pave the way for a new treaty, as long as we can ensure it isn't a ploy to strengthen their ranks."|"At least she isn't angling for retribution."}

*if giantchat
    @{(giantresponse) He shakes his head. "I would have us hear them out."|"I agree."|"I agree."|"I agree, as long as it isn't a ploy to strengthen their ranks."}

    You stroll deeper into the grove, falling into @{(distantares) a somewhat comfortable|comfortable} silence.
    *goto drakonnest
*elseif wentwithares = false
    It's your turn to bear everyone's scrutiny. 

    @{(giantresponse) Zeus gives you an approving nod|Zeus narrows his eyes at you|Zeus gives you an approving nod|Zeus narrows his eyes at you}.

    @{(giantresponse) Ares shakes his head. "I would have us hear them out."|Your father places a staying hand on your shoulder|"Indeed," your father agrees. "We should at least hear them out."|"My daughter is right. Repatriation might offer an adequate resolution, as long as we can guarantee it isn't a ploy to strengthen their ranks," your father says. Then, almost playfully, he adds, "No harm in hearing them out."}
    
    "Oh, we'll hear them out," Zeus snorts.

    Your mother leans forward. "What do you propose?"

    You're almost certain she used that word on purpose.
    *goto feastsetup1
*else
    @{(giantresponse) Zeus's tone is that of an accusation. Ares tenses beside you upon hearing it|Your father's words surprise you. You didn't expect him to agree with you|Your mother's words don't surprise you. When she isn't addressing those she's related to, she can be very diplomatic|Your father's words surprise you. You didn't expect him to agree with you}.

    Whatever might've followed is forgotten, however, when Hera spots you and Ares hovering by the pond.  
    *goto feastsetup

*label feastsetup
*page_break

"There you are!" she exclaims, @{(giantchat) greeting you with a tight smile|she exclaims, vanquishing the concern from her features}. "Did you enjoy your stroll?"

"Yes, did you?" your mother adds, narrowing her eyes at you. The look your father shoots you isn't as barbed, but it isn't exactly reassuring either.

"Greatly," Ares quips, perching on a velvet bench and helping himself to some grapes.

"I'm glad to hear it, son," Zeus says, and it's the most warmth he's shown him since you arrived. As though he's proud of him for sneaking off with you. As though it's something he would've done.

Ares notices too, and shifts uncomfortably in his seat.

"In fact, you've arrived at the perfect time to hear my proposal for dealing with the Giants."

@{(aresmarriagetalk) What is it with this family and the use of that word?|Did he use that word on purpose?}

Everyone except the harpist goes still, but the thunder god is undeterred.

*label feastsetup1
*page_break

"Let's meet them on neutral ground," Zeus says. "Someplace in Hellas ought to do the trick, and a feast ought to be the lure." He glances at Persephone. "A great feast in honor of spring. On the eve before Demeter and yourself begin your task. It shall be a new moon, and thus a clean slate."

"What if they don't bite?" Ares asks. 

Zeus shakes his head. "Be it repatriation, territory, or revenge, they want something. They'll bite."

Persephone cocks her head at him. "So we reel them in. Then what?"

"We must present a united front." He glances at you, then at Ares. "Remind them of our generosity, and our might. Then we hear them out."

"And if they say something we don't like?" Hera asks, frowning.

Zeus's grin is roguish, and dangerous. "We feast!"

"Won't that wreak havoc on the mortal realm?" his wife presses.

"We won't let it," Zeus dismisses her. "Besides, they too could use a reminder of our generosity and might."

*page_break

This is it. You feel it in the way your parents' eyes fix on you, and Zeus's and Heras's fix on Ares. The moment they'll bring up exactly what this united front entails. 

Your union. 

Then the sudden flap of wings captures your attention.

*page_break Look Up

A rainbow plunges into the spot on the lawn where Iris lands. It doesn't seem so bright in the face of Olympus's splendor.

Zeus frowns. "Iris. Is all well?"

"Apologies, my king." Their eyes are a wary yellow. "Prince Ares's presence is required in Hellas. A fight with the Medians has broken out on the Eastern border, and the people are calling for aid."

Ares leaps to his feet.

"Can't it wait? We have important matters to discuss," Hera interjects, eyes darting between you and her son.

"Mother, please. This is what my worship is for."

Hera nods, but you can tell she isn't pleased. Not that it bothers Ares. He turns to face you.

"I'm sorry our reunion was cut short. I'll be sure to make it up to you once this matter is settled."

*fake_choice
    #"I look forward to it." I smile.
        You catch the pink flush that spreads across his cheeks.
    #"If you must," I tease.
    #I wave him off. "No rush."
    #I merely nod.

"Stop standing there, boy. You have some skirmish to settle, don't you?"

Ares ignores his father and bows before your parents.

Then he follows Iris into the sky, encased in a fiery glow that leaves behind a reddish trail.

*page_break

Hera clears her throat. "How unfortunate. I hope you will forgive the intrusion."

"He was right to go," Hades reassures her.

"Child's play," Zeus mutters, making Hera sigh. "What?"

They begin arguing under their breath. Your father takes the opportunity to address your divan.

"We ought to make a move as well," he murmurs. 

He's trying to hide it, but you can tell he's growing restless; he seldom spends this long away from his work.

"Yes, well, it seems it's our other child's turn to dishonor us by running off to Fates know where, to do Fates know what," your mother murmurs back.

Right enough, Zagreus and the harpist are nowhere to be found.

"$!{name}," your father practically pleads.

*page_break Find Zagreus

You excuse yourself, though you doubt Hera and Zeus hear you; they're far too focused on their little spat.

You @{(wentwithares) venture back into the apple orchard|wander into the apple orchard surrounding the gardens}, following the sound of distant laughter all the way to its edge.

Then a strange scent catches your attention. One that both belongs among the greenery and doesn't. Sweet and floral, but overwhelmingly so. Wild roses in the sun, just before they wilt.

"Look what the harpy dragged in," someone says behind you.

*page_break Face Them

It isn't Zagreus, nor the harpist, but the most beautiful goddess you've ever seen.

She leans against a tree, eyeing you like you're a bug she'd like to step on. Golden hair pours down her back, thick and shimmery as nectar, and her flawless tan skin glows with a nacre sheen. Her gown leaves little of it to the imagination, made of a fabric so fine it's translucent. Sea-shell brooches rest atop her clavicles and rose earrings bloom by her long, swan-like neck.

Aphrodite, goddess of love and beauty. And, if the rumors are to be believed, Ares's one-time lover.

How do you greet her?

*set metrival true

*fake_choice
    #"Pleased to make your acquaintance," I say politely.
        *set diplomacy %+10
        "Are you, now?"
        
        Her voice wraps around you like a snake.

        "Indeed." You lower your head but your gaze remains fixed on hers. "It isn't often I encounter Olympians, let alone ones with such a storied reputation."
    #"Got a problem?" I say, lifting my chin defiantly.
        *set charm %-10
        "Don't @{(flightstyle) let your feathers get all ruffled|get your shadows in a twist|go kicking up a fuss} now." 

        She pretends to examine one of her nails. There's no need; they're as perfect as the rest of her. 
        
        You cross your arms over your chest.

        "If you're looking for a fight, I'm more than happy to oblige."
    #"I'm honored to be in your presence, goddess," I say respectfully.
        *set dutiful %+10
        "Well, isn't that cute." 
        
        She crosses her arms over her chest. There's a sharpness to her tone, an edge to her casual demeanor.

        "It's a shame the Fates didn't grant me the privilege sooner."
        
Her laugh is the only ugly thing about her. You notice her handmaiden standing a few trees behind her, stirring uncomfortably at the sound.

"Please." Aphrodite gives you a dismissive wave. "There's no need for that."

Her eyes narrow. They're a blue so pure you doubt even Iris could imitate it. 

"Then to what do I owe the pleasure of your company?"

"As you can see, I have many virtues." She twists a lock of hair around her finger. "But sharing isn't one of them. My toys are mine, and mine alone. Understood?"

*page_break

You study her carefully. Regardless of how you may feel about Ares, making an enemy out of such a powerful Olympian would be unwise. She has started wars for less. 

But if you come across as weak, your worship might dwindle, and neither gods nor mortals look kindly upon a goddess who can't handle herself.

Then again, she could also make a powerful ally. 

How do you react?

*choice
    #Reason with her; you're not her enemy.
        "I understand we're both in a difficult position. I see no reason to make it more difficult by throwing petty catfighting into the mix."

        *if diplomacy > 30
            *set befriendrival %+10
            *set pantheonplayer %+10
            *set olympusinfluence %+10  
            You let the words dangle between you like an olive branch, keeping your stance loose and your expression friendly as she sizes you up.

            Then she pushes herself off the tree, flips back her hair and shrugs. "I suppose you're right."

            "I'm glad we could clear the air," you say.
            
            "Don't push it, harpymeat." She turns to her handmaiden. "Why are you standing there? I would like to bathe."

            "Of course, my lady." The nymph scurries off, cheeks bright.
            
            Aphrodite tosses you a final smirk, then follows after her.

            If nothing else, you've got to admire her commitment to haughtiness.
            *goto postconfrontation
        *else
            *set befriendrival %-10
            *set olympusinfluence %-10
            She straightens, breaking the spell of casual allure. Her burnished hair ripples around her like flames, her skin is ablaze. 
            
            Behind her, her handmaiden takes a few steps back. You realize you've done the same when your back hits the trunk of a tree.

            "How dare you patronize me?"

            "I didn't mean…"

            She makes a sharp hushing sound, startling you into silence.

            "Trust me," she warns, "you do not want to get on my bad side."

            Then she turns her back to you, hurtling off. Her handmaiden flinches at her mistress's approach, letting out a sigh of relief when Aphrodite stomps past her before following.

            You take a moment to collect yourself, pressing a hand to your chest to steady your raging heartbeat.
            *goto postconfrontation
    #Intimidate her; you're not to be messed with.
        *set intimidatedaphrodite true 
        *if charm < 70
            *set befriendrival %-10
            *set maverickgoddess %+10
            *set olympusinfluence %+10
            You close the distance between you and square up to her, @{(flightstyle) spreading your wings wide|encased in a fire of shadow|standing tall and proud}.

            "Keep harping on like that and you'll have no virtues left when I'm done with you," you growl. Then, in a tone that mimics hers, you add, "Understood?" 

            She takes a step back. Even her handmaiden appears rattled, glancing at you with fear-wide eyes.

            "Well?" you add. 

            Aphrodite manages to recover some of that haughty aura, but she doesn't come any closer. 

            "You've been warned," she utters.

            Then she turns around, gesturing for her handmaiden to follow.

            "Run along now," you call after her with a smirk.
            *goto postconfrontation
        *else
            *set maverickgoddess %-10
            You close the distance between you but the scent of roses clogs your throat as soon as you reach her. You try to hide your cough by @{(flightstyle) spreading your wings wide|summoning a wave of shadows|standing tall despite it}, but it's no use.

            "Keep harping on like that and you'll have no virtues left when I'm done with you," you rasp. Fates, that smell is strong. "Understood?" 

            She lifts an eyebrow. Then she laughs. It's worse this time around. A full on cackle you're certain even the oak trees can hear.

            "Brilliant. That was absolutely brilliant."

            You blink. Few things can snuff the fight out of you. Turns out Aphrodite is one of them. 

            "I meant it," you grumble.

            "I'm sure you do." She straightens, wiping away tears. "Let's do this again soon, yes?"

            She turns around, shaking her head. Her handmaiden flashes you a commiserating smile before following, leaving you to collect the pieces of your shattered dignity.
            *goto postconfrontation
    #Kill her with kindness; flattering her will throw her off.
        "Understood." You avert your gaze, bite your lip. "I could never compete with a beauty such as yourself anyway."

        *if cunning > 35
            *set befriendrival %+5
            *set maverickgoddess %+10
            *set worship %+10
            Her gaze softens and she smiles. You keep from rolling your eyes.

            "It's true what mortals say about you, you know," you add meekly.

            "What's that?"

            "That you're the fairest of all Olympian goddesses."

            "As if it was ever in question." She lets out a satisfied smirk then tosses you an appreciative glance. "Don't be so hard on yourself, harpymeat. You're rather easy on the eyes too."

            The handmaiden stares at you agape. You get the feeling her mistress isn't given to compliments. When Aphrodite turns around, you toss her a wink. You're certain she'll be spreading the word about this little exchange. Good. The realms should know how you charmed Olympus's most charming goddess.

            And worship you for it, of course.
            *goto postconfrontation
        *else
            *set befriendrival %-15
            *set maverickgoddess %-10
            *set olympusinfluence %-10
            The veneer of casual allure disappears. Aphrodite straightens, points her glare at you like a sharpened spear. 

            "Drop the act, harpymeat," she snaps, her hair dripping around her like liquid fire. "You're no meek damsel."

            "Fine," you sigh. "But I'm not going to back off from Ares."

            Unless that's what [i]you[/i] want. But she doesn't need to know that.

            "I'm warning you, you don't want to get on my bad side," she growls.

            "Now that you mention it, that eye does seem slightly lower than that one."

            She bares her teeth at you before turning around, gesturing for her handmaiden to follow.
            
            Then she's gone, leaving you to your hammering heart and rushing thoughts.
            *goto postconfrontation

*label postconfrontation
*page_break

So the rumors are true. Aphrodite had an affair with Ares.
 
You wonder if Hephaestus, God of Fire and Blacksmiths, and Aphrodite's husband, knows. Perhaps he doesn't care. There are plenty of unions where that's the case. Theirs was devised by Zeus. You didn't attend, but you remember the fanfare surrounding their nuptials. How the celebrations seemed to stretch for weeks. How mortals showered worship on the pair, and on the thunder god for bringing them together. 

And yet, whispers of unhappiness have followed them since.

Would that happen to you and Ares, should you agree to marry? @{(marriage) And would it matter, if the realms were safe?|And would you care, if you had power and wealth because of it?|You doubt your heart would recover.|It certainly makes you glad you have no interest in doing so.}

His involvement is rather puzzling, however. A miserable spouse having an affair isn't unexpected, but he seems so noble. So unlike the kind of god given to this kind of dalliance.

@{(background) You would know; you've met plenty|Then again, your former lover had been sweet and charming too, and that never stopped him from betraying you many times over|But what do you know? After all, matters of the heart are a mystery to you|You can't blame him for following his heart, however misguided it may be. You often regret not doing so yourself}.

Still, the discovery makes you feel…

*fake_choice
    *if fancyares
        #A little thrown off. I like Ares and this could complicate things.
            *set Ares %+10
    #Worried about Ares. It's been a while, but he's still my friend.
            *set Ares %+5
            *set aresfriends true
    #Glad for the confirmation. I could use this knowledge to my advantage.  
        *set cunning %+10
        *set Ares %-10
    *if intimidatedaphrodite = false
        #Saddened. It shouldn't lead to Aphrodite and me being at odds.
            *set ruthless %-5
    #Indifferent. Whatever is or isn't between them is none of my concern.
        *set indifferentaprhodite true
        *set diplomacy %+5
        *set Ares %-5

Sighing, you continue your search for your brother.

At this point, only the Fates know for sure whether Ares will become your husband, your ally, or a foe.
*choice
    #Continue to the next chapter.
        *finish Chapter 3
    *if (not(choice_randomtest)) #Restore to the previous checkpoint.
        *restore_checkpoint